' ******************************************************************
' PROGRAMM: Einfaches Aufzugprogramm für zwei Stockwerke (EG, 1. OG)
'           (ohne Stockwerksanzeige, ohne Ruftasten)
' 
' Erläuterung: 
' Das Programm arbeitet nur mit den Zieltasten. 
' Zunächst fährt der Lift ins Erdgeschoss, um eine definierte
' Ausgangsposition zu erhalten. Dann kann mit den Zieltasten 1 und 2
' das gewünschte Stockwerk ausgewählt werden.
' 
' Verwendung von Programmverzweigungen und -schleifen.
'
' Version: 1
' *******************************************************************
' Dateiname: lift2.cbp
' Programmautor: Fies
' Arbeitsplatz:
' Programmiert am: 21. 12. 99
' Programmiersprache: CIUS_V2
' ==============================================================
' Vereinbarungsteil
'
' Modell: CIUS-Aufzug
' 
' Anschlussbelegungen des Interfaces:
'   Digitale Ausgänge (DOUTs):          Digitale Eingänge (DINs):
'     DOUT  1: a                          DIN  1: Zieltaste EG
'     DOUT  2: b                          DIN  2: Zieltaste 1. OG
'     DOUT  3: c                          DIN  3: Zieltaste 2. OG
'     DOUT  4: d                          DIN  4: Zieltaste 3. OG
'     DOUT  5: e                          DIN  5: Ruftaste EG
'     DOUT  6: f                          DIN  6: Ruftaste 1. OG
'     DOUT  7: g                          DIN  7: Ruftaste 2. OG
'     DOUT  8:                            DIN  8: Ruftaste 3. OG
'     DOUT  9: LED EG                     DIN  9: Stoppkontakt EG
'     DOUT 10: LED 1. OG                  DIN 10: Stoppkontakt 1. OG
'     DOUT 11: LED 2. OG                  DIN 11: Stoppkontakt 2. OG
'     DOUT 12: LED 3. OG                  DIN 12: Stoppkontakt 3. OG
'     DOUT 13:                            DIN 13: Reedkontakt EG
'     DOUT 14:                            DIN 14: Reedkontakt 1. OG
'     DOUT 15:                            DIN 15: Reedkontakt 2. OG
'     DOUT 16:                            DIN 16: Reedkontakt 3. OG
'
'   Analoge Ausgänge (AOUTs):           Analoge Eingänge (AINs):
'     AOUT  1: Aufzugmotor (aufwärts)     AIN  1:
'     AOUT  2: Aufzugmotor (abwärts)      AIN  2:
'     AOUT  3:                            AIN  3:
'     AOUT  4:                            AIN  4:
' 
'   Schrittmotoren:
'     SMOT1:
'     SMOT2:
' =================================================================
'
' Hauptprogramm:
' -------------

'Aufzug ins EG:

DO WHILE DIN(9)=1       'Solange Stopp-Kontakt 1 nicht betätigt ist
  AMOT 1, RIGHT, 255    'Aufzugmotor mit voller Spannnung abwärts
LOOP
AMOT 1, OFF, 0           'Aufzugmotor stopp

'Aufzugfahrt auf Anfrage

DO
  IF DIN(10)=0 AND DIN(1)=0 THEN      'Wenn Aufzug im 1.OG UND Zieltaste EG betätigt
    AMOT 1, RIGHT, 255                'Aufzugmotor mit voller Spannung abwärts
    DO                                'Leere Schleife bis zum Erreichen des EG
    LOOP UNTIL DIN(9)=0
    AMOT 1, OFF, 0                    'Aufzugmotor stopp
  ELSEIF DIN(9)=0 AND DIN(2)=0 THEN   'Wenn Aufzug im EG UND Zieltaste 1.OG betätigt
    AMOT 1, LEFT, 255                 'Aufzugmotor mit voller Spannung aufwärts
    DO                                'Leere Schleife bis zum Erreichen des 1. OG
    LOOP UNTIL DIN(10)=0
    AMOT 1, OFF, 0                    'Aufzugmotor stopp
  ENDIF
LOOP